Audio Codec

/**
 * @file streams-generator-i2s.ino
 * @author Phil Schatzmann
 * @modified by Karthik E
 * @brief see https://github.com/pschatzmann/arduino-audio-tools/blob/main/examples/examples-stream/streams-generator-i2s/README.md 
 * @copyright GPLv3
 */
 
#include <Wire.h>
#include "AudioTools.h"
#include "PCBCUPID_NAU8325.h" // install https://github.com/pcbcupid/PCBCUPID-NAU8325.git

AudioInfo info(44100, 2, 16);
SineWaveGenerator<int16_t> sineWave(32000); // subclass of SoundGenerator with max amplitude of 32000
GeneratedSoundStream<int16_t> sound(sineWave); // Stream generated from sine wave
I2SStream i2s;
StreamCopy copier(i2s, sound); // copies sound into i2s

// Use our NAU8325 codec configuration
TwoWire I2Cbus(0);
PCBCUPID_NAU8325 nau8325(I2Cbus);

void setup(void) {  
  // Open Serial 
  Serial.begin(115200);
  while(!Serial);
  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Info);

  // Initialize I2C for NAU8325
  Serial.println("Checking I2C...");
  I2Cbus.begin(4, 5);

  delay(10);

  // Initialize NAU8325 codec
  if (!nau8325.begin()) {
    Serial.println("NAU8325 init failed");
    while (1);
  }
  nau8325.setVolume(0xFF, 0xFF); // Set max volume
  Serial.println("NAU8325 detected and configured!");

  // Start I2S
  Serial.println("starting I2S...");
  auto config = i2s.defaultConfig(TX_MODE);
  config.pin_ws = 8;
  config.pin_bck = 18;
  config.pin_data = 7;
  config.pin_mck = 19;
  config.is_master = true;
  config.use_apll = false;
  config.i2s_format = I2S_STD_FORMAT;
  config.copyFrom(info); 
  i2s.begin(config);

  // Setup sine wave
  sineWave.begin(info, N_B4);
  Serial.println("started...");
}

// Arduino loop - copy sound to out 
void loop() {
  copier.copy();
}

#include <SPI.h>
#include <SD.h>
#include <Wire.h>
#include "AudioTools.h"
#include "AudioTools/AudioCodecs/CodecMP3Helix.h"
#include "PCBCUPID_NAU8325.h" // install https://github.com/pcbcupid/PCBCUPID-NAU8325.git

/* === Pin configuration === */

// SD Card configuration
#define MY_SCK 11
#define MY_MISO 3
#define MY_MOSI 2
#define MY_CS 1

// I2S (NAU8325) configuration
#define I2S_WS 24
#define I2S_BCK 25
#define I2S_DATA 23
#define I2S_MCLK 22

// === Audio settings ===
const uint32_t sample_rate = 44100; // sample_rate can be changed as per the song frequency (e.g. 48000, 32000, 16000, 8000, 96000, 12000, 64000)
const uint16_t ratio = 256;         // ratio supported by NAU8325 (e.g. 256, 400, 500)
const uint8_t bits = 16;            // bit depth (e.g. 16, 24, 32)

// === Objects ===
TwoWire I2Cbus(0);
PCBCUPID_NAU8325 nau8325(I2Cbus); 

// Audio Stream Configuration 
I2SStream i2s;
MP3DecoderHelix decoder;
EncodedAudioStream encodedStream(&i2s, &decoder);
StreamCopy copier;
File audioFile;

void setup() {
  Serial.begin(115200);
  delay(10);
  Serial.println("=== NAU8325 SD EXAMPLE ===");

  I2Cbus.begin(4, 5);

  if (!nau8325.begin()) {
    Serial.println("NAU8325 init failed");
    while (1)
      ;
  }

  nau8325.setVolume(0xFF, 0xFF); // Setting NAU8325 at maximum volume
  Serial.println("NAU8325 Turned ON");

  // SD card initialization
  SPI.begin(MY_SCK, MY_MISO, MY_MOSI, MY_CS);
  if (!SD.begin(MY_CS)) {
    Serial.println("SD card init failed");
    while (1)
      ;
  }

  audioFile = SD.open("/Dwapara.mp3"); // Enter the MP3 song name from your SD card followed by "/" e.g.: "/music.mp3"
  if (!audioFile || audioFile.isDirectory()) {
    Serial.println("MP3 file not found");
    while (1)
      ;
  }

  // I2S Config
  auto config = i2s.defaultConfig(TX_MODE);
  config.sample_rate = sample_rate;
  config.bits_per_sample = bits;
  config.channels = 2;
  config.pin_bck = I2S_BCK;
  config.pin_ws = I2S_WS;
  config.pin_data = I2S_DATA;
  config.pin_mck = I2S_MCLK;
  config.i2s_format = I2S_STD_FORMAT;
  config.use_apll = false;

  i2s.begin(config);
  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Info);
  decoder.begin();
  copier.begin(encodedStream, audioFile);

  Serial.println("Playback started!");
}

void loop() {
  if (!copier.copy()) {
    // Sending empty values to auto turn off NAU8325
    Serial.println("Playback done. Sending silence...");
    int16_t zero = 0;
    for (int i = 0; i < 2048 * 2; i++) {
      i2s.write((uint8_t *)&zero, sizeof(zero));
    }
    while (1)
      ;
  }
}

// ========== SD Card File Listing ==========
void listDir(fs::FS &fs, const char *dirname, uint8_t levels) {
  Serial.printf("Listing directory: %s\n", dirname);
  File root = fs.open(dirname);
  if (!root || !root.isDirectory()) {
    Serial.println("Failed to open directory");
    return;
  }

  File file = root.openNextFile();
  while (file) {
    if (file.isDirectory()) {
      Serial.print("  DIR : ");
      Serial.println(file.name());
      if (levels) listDir(fs, file.path(), levels - 1);
    } else {
      Serial.print("  FILE: ");
      Serial.print(file.name());
      Serial.print("  SIZE: ");
      Serial.println(file.size());
    }
    file = root.openNextFile();
  }
}